//############################################################
// CONSTANTS
//############################################################
 
//############################################################
// VARIABLES
//############################################################
 
var __flameCount:Number;
 
 
 
//############################################################
//FUNCTIONS
//############################################################
 
//------------------------------------------------------------
// Init
//------------------------------------------------------------
function Init():Void
{
	// variables
	__flameCount = 0;
 
	// dragon head mover
	emitter_mc.onEnterFrame = EmitterMover;
 
	// spit fire on mouse up
	_root.onMouseUp = SpitFire;
}
 
//------------------------------------------------------------
// SpitFire
//------------------------------------------------------------
function SpitFire():Void
{
	// set flame count
	__flameCount = 10;
}
 
//------------------------------------------------------------
// CreateFlame
//------------------------------------------------------------
function CreateFlame():Void
{
	// add flame movie clip
	var depth:Number = _root.getNextHighestDepth();
	var thisFlame_mc:MovieClip =
		_root.attachMovie("flame", "flame", depth);
 
	// set flame position
	thisFlame_mc._x = emitter_mc._x;
	thisFlame_mc._y = emitter_mc._y;
 
	// flame rotation is random
	thisFlame_mc._rotation = 360 * Math.random();
 
	// set azimuth and speed
	thisFlame_mc.azimuth 	= -35;
	thisFlame_mc.speed	= 25;
 
	// mover
	thisFlame_mc.onEnterFrame = FlameMover;
}
 
//------------------------------------------------------------
// EmitterMover
//------------------------------------------------------------
function EmitterMover():Void
{
	// if __flameCount > 0, spit flame
	if (__flameCount > 0) {
		// create the actual flame movie clip
		CreateFlame();
		__flameCount--;
	}
}
 
//------------------------------------------------------------
// FlameMover
//------------------------------------------------------------
function FlameMover():Void
{
	// move speed (add lift speed)
	this._x -= this.speed * Math.cos(this.azimuth * Math.PI / 180);
	this._y -= this.speed * Math.sin(this.azimuth * Math.PI / 180) + 5;
 
	// speed decay
	this.speed *= 0.95;
}
 
 
 
//############################################################
// MAIN
//############################################################
Init();